Программирование на Visual Basic 5
Опубликовано без приложений в "Информатике" №№ 23, 28, 31 за 1999 год

Documents.Add

Dim objVar As Object

Dim objVar As Word.Selection

Set objVar = CreateObject(“Word.Selection”)

Set objVar = New Word.Selection

Set objVar = GetObject(“”, "Word.Selection")

Private Sub cmdWord_Click()
 Dim objWord As Object 'Объявляем объект
 On Error Resume Next '- Обратите внимание на эту инструкцию:
 '"В случае ошибки (On Error) продолжать (Resume) со
 ' следующей (Next) инструкции"
 'Открываем объект, установив ссылку на активный объект Word:
 Set objWord = GetObject(, "Word.Application")
 'Если такого объекта не оказалось,
 If objWord Is Nothing Then
  'то открываем его, запустив Word на выполнение:
  Set objWord = New Word.Application
  '(То же можно сделать, например, так:
  'Set objWord = CreateObject("Word.Application")  )
  'Если и после этого ссылка не удалась,
  If objWord Is Nothing Then
   'то распишемся в своем бессилии:
   MsgBox "Создать объект не удается!"
  End If
 End If
 objWord.Visible = True ' - Иначе окна приложения не увидим!
 'Откроем, пожалуй, наш документ:
 objWord.Documents.Open "C:\Мои документы\MyDoc.doc"
 'Уничтожаем объект (“Знак хорошего вкуса и традиций пример”):
 Set objWord = Nothing
End Sub

Option Explicit 'Контроль за явной объявленностью 
                    'переменных
Private objElem As Stack

Public Child As Stack

Public Property Get Value() As Variant
End Property
Public Property Let Value(ByVal vNewValue As Variant)
End Property

Private mvar_Value As Variant

Value = mvar_Value

Public Property Get Value() As Variant
 Value = mvar_Value
End Property

Public Property Let Value(ByVal vNewValue As Variant)
 mvar_Value = vNewValue
End Property

Public Event Initilize()
Public Event Terminate()
Public Event Void()

Option Explicit
Private objElem As Stack
Public Child As Stack
Private mvar_Value As Variant
Public Event Initilize()
Public Event Terminate()
Public Event Void()
Public Property Get Value() As Variant
 Value = mvar_Value
End Property

Public Property Let Value(ByVal vNewValue As Variant)
 mvar_Value = vNewValue
End Property

Public Sub Push()
 Set objElem = New Stack 'Создаем новый объект со ссылкой objElem
 Set objElem.Child = Me.Child 'Ссылаемся сыном нового объекта
                                        'на сына текущего объекта 
 objElem.Value = Me.Value 'Копируем данное из текущего-в новый
 Set Me.Child = objElem 'Ссылаемся сыном текущего на новый
End Sub
Public Sub Pop()
 If Me.Child Is Nothing Then
  RaiseEvent Void
  Exit Sub
 End If
 Set objElem = Me.Child 'Сохраняем ссылку на сына текущего объ.
 Set Me.Child = Nothing 'Уничтожаем сына текущего объекта
 Set Me.Child = objElem.Child 'На место сына подставляем внука
 Me.Value = objElem.Value 'В текущий копируем данное, бывшее в
 Set objElem = Nothing 'уничтоженном сына и уничтожаем ссылку
End Sub                    'на этого сына

Private Sub Class_Initialize()
 RaiseEvent Initilize
End Sub

Private Sub Class_Terminate()
 RaiseEvent Terminate
End Sub

Dim WithEvents Elem As Stack
Dim i As Integer, j As Integer 'i - натуральный ряд, заносимый в стек 
'j - флаг, устанавливаемый при чтении из пустого стека
Private Sub cmdClass_Click()
 Set Elem = New Stack
 Elem.Value = -1 'При пустом стеке объект хранит -1
 cmdClass.Enabled = False
End Sub
Private Sub cmdPop_Click()
 Elem.Pop
 If j = 1 Then
  MsgBox Str(Elem.Value)
  i = i - 1
 End If
End Sub
Private Sub cmdPush_Click()
 If j = 0 Then
  j = 1
 End If
 i = i + 1
 Elem.Push 'При каждом вызове в стек заносятся числа
 Elem.Value = i
End Sub
Private Sub Elem_Void()
 MsgBox "Стек пуст"
 j = 0
End Sub

'Код метода для абстрактного класса Szivotnye
Public Sub Sound(ByVal Tone As Double, _
                    ByVal Duration As Double, ByVal Sort As Integer)
 'Здесь какой-то код, представляющий общую реализацию метода
End Sub

'Один из классов сервера, использующий абстрактный класс Szivotnye:
Implements Szivotnye 'Объявляем класс Szivotnye интерфейсом
Private objSziv As Szivotnye 'Объявляем переменную класса интерфейса
'Обработчик инициализации объекта класса сервера:
Private Sub Class_Initilise() 
 Set objSziv = New Szivotnye 'Создание объекта интерфейса
End Sub

'Переопределение метода:
Private Sub Szivotnye_Sound(ByVal Tone As Double, _
                       ByVal Duration As Double, ByVal Sort As Integer)
 'Сначала - повторное использование кода общей реализации:
 Call objSziv.Sound(Tone, Duration, Sort)
 'А потом -  можно добавить и дополнительный код
End Sub

Private Sub UserControl_Resize()
 With lblTime
  .Font.Size = UserControl.ScaleHeight * 41 / 79.8
  .Left = (UserControl.ScaleWidth - .Width) / 2
  .Top = (UserControl.ScaleHeight - .Height) / 2
 End With
End Sub 

Private Sub tmrSec_Timer()
 Static strs As String, tmr As Date
 tmr = Time
 strs = Format(tmr, "hh:nn:ss")
 lblTime.Caption = strs
End Sub

Option Explicit
Event Change()
Event Timer()
Public Property Get Enabled() As Boolean
    Enabled = UserControl.Enabled
End Property

Public Property Let Enabled( _
           ByVal New_Enabled As Boolean)
    UserControl.Enabled() = New_Enabled
    PropertyChanged "Enabled"
End Property

Public Property Get TimeCaption() As String
    TimeCaption = lblTime.Caption
End Property

Public Property Let TimeCaption( _
           ByVal New_TimeCaption As String)
    lblTime.Caption() = New_TimeCaption
    PropertyChanged "TimeCaption"
End Property

Public Property Get Interval() As String
    Interval = txtInt.Text
End Property

Public Property Let Interval( _
           ByVal New_Interval As String)
    txtInt.Text() = New_Interval
    PropertyChanged "Interval"
End Property

Public Property Get Font() As Font
    Set Font = lblTime.Font
End Property

Public Property Set Font(ByVal New_Font As Font)
    Set lblTime.Font = New_Font
    PropertyChanged "Font"
End Property

Public Property Get BackColor() As OLE_COLOR
    BackColor = lblTime.BackColor
End Property

Public Property Let BackColor( _
           ByVal New_BackColor As OLE_COLOR)
    lblTime.BackColor() = New_BackColor
    PropertyChanged "BackColor"
End Property

Public Property Get ForeColor() As OLE_COLOR
    ForeColor = lblTime.ForeColor
End Property

Public Property Let ForeColor( _
           ByVal New_ForeColor As OLE_COLOR)
    lblTime.ForeColor() = New_ForeColor
    PropertyChanged "ForeColor"
End Property

Public Property Get TypeInterval() As Boolean
    TypeInterval = optType(0).Value
End Property

Public Property Let TypeInterval(ByVal New_TypeInterval As Boolean)
     optType(0).Value() = New_TypeInterval
    PropertyChanged "TypeInterval"
End Property

Public Function Start() As Variant
End Function

Public Function Stopp() as Variant
End Function

Public Function Check() As Variant
End Function

Private Sub UserControl_ReadProperties( _
               PropBag As PropertyBag)
    UserControl.Enabled = PropBag.ReadProperty( _
               "Enabled", True)
    lblTime.Caption = PropBag.ReadProperty( _
               "TimeCaption", "00:00:00")
    txtInt.Text = PropBag.ReadProperty( _
               "Interval", "00:00:00")
    optType(0).Value = PropBag.ReadProperty( _
               "TypeInterval", True)
    Set Font = PropBag.ReadProperty( _
               "Font", Ambient.Font)
    lblTime.BackColor = PropBag.ReadProperty( _
               "BackColor", &HC0C0C0)
    lblTime.ForeColor = PropBag.ReadProperty( _
               "ForeColor", &H8000&)
End Sub

Private Sub UserControl_WriteProperties( _
               PropBag As PropertyBag)
    Call PropBag.WriteProperty( _
               "Enabled", UserControl.Enabled, True)
    Call PropBag.WriteProperty("TimeCaption", _
         lblTime.Caption, "00:00:00")
    Call PropBag.WriteProperty( _
               "Interval", txtInt.Text, "00:00:00")
    Call PropBag.WriteProperty( _
               "TypeInterval", optType(0).Value, True)
    Call PropBag.WriteProperty( _
               "Font", Font, Ambient.Font)
    Call PropBag.WriteProperty( _
               "BackColor", lblTime.BackColor, &HC0C0C0)
    Call PropBag.WriteProperty( _
               "ForeColor", lblTime.ForeColor, &H8000&)
End Sub

Sub About1()
 frmAbout.Show
End Sub

Dim i As Integer, f As Integer
Dim t_txtInt As Date
Dim sh As Single, sw As Single
'i - счетчик переходов между функциями Часы/Будильник
'f -флаг задания начала отсчета в функции Будильника
'sh, sw - хранители размеров ПЭУ на форме клиента для их
'восстановления после работы в режиме установки 
't_txtInt - величина заданного интервала для Будильника
Const C_height = 1596 'Проектная высота UserControl
Const C_width = 3324 'Проектная ширина UserControl
Const C_koef = 41 / 79.8 'Коэффициент отношения высот
'шрифта отображения времени в ПЭУ Clock и самого ПЭУ
Const С_interv = 100 'интервал таймера tmrSec

Private Sub UserControl_DblClick()
  'Запоминаем размер ПЭУ
  sh = UserControl.Height
  sw = UserControl.Width
  'Устанавливаем проектный размер “изнанки” ПЭУ
  UserControl.Height = C_height
  UserControl.Width = C_width
  SSTab1.Visible = True
  txtInt.Visible = True
  cmdStart.Visible = True
  cmdStop.Visible = True
  cmdCheck.Visible = True
  lblTime_1.Visible = True
  Label3.Visible = True
  Label4.Visible = True
  optType(0).Visible = True
  optType(1).Visible = True
End Sub

Private Sub SSTab1_DblClick()
  SSTab1.Visible = False
  'Возврат к исходному размеру ПЭУ
  UserControl.Height = sh
  UserControl.Width = sw
End Sub

Private Sub cmdCheck_Click()
 If i Mod 2 = 0 Then 'Функция будильника
   cmdCheck.Caption = "В режим часов"
   cmdStart.Enabled = True
   optType(0).Enabled = True
   optType(1).Enabled = True
   f = 0
   If optType(0).Value = True Then
    tmrSec.Interval = 0
    lblTime.Caption = "00:00:00"
    lblTime_1.Caption = "00:00:00"
   End If
 Else 'Функция часов
   cmdCheck.Caption = "В режим будильника"
   cmdStart.Enabled = False
   optType(0).Enabled = False
   optType(1).Enabled = False
   tmrSec.Interval = С_interv
 End If
 i = i + 1
End Sub

Private Sub cmdStart_Click()
 cmdStart.Enabled = False
 cmdCheck.Enabled = False
 cmdStop.Enabled = True
 t_txtInt = CDate(txtInt.Text)
 tmrSec.Interval = С_interv 'Включаем таймер
End Sub

Private Sub cmdStop_Click()
 cmdStart.Enabled = True
 cmdCheck.Enabled = True
 cmdStop.Enabled = False
End Sub

Public Function Start() As Variant
 Call cmdStart_Click
End Function

Public Function Check() As Variant
 Call cmdCheck_Click
End Function

Public Function Stopp() As Variant
 Call cmdStop_Click
End Function

Private Sub optType_Click(Index As Integer)
 optType(Index).Value = True
 optType(1 - Index).Value = False
 If optType(1).Value = True Then
  tmrSec.Interval = С_interv 'Включаем таймер
 Else
  tmrSec.Interval = 0
  lblTime.Caption = "00:00:00"
  lblTime_1.Caption = "00:00:00"
 End If
End Sub

Private Sub tmrSec_Timer()
  Static strs As String, tmr As Date, tmr0 As Date, tmrt As Date
  tmr = Time
  If cmdStop.Enabled = True Then
   If optType(0).Value = True Then
    If f = 0 Then
     tmr0 = tmr
     f = 1
    Else
     tmrt = tmr - tmr0
     lblTime.Caption = Format(tmrt, "hh:nn:ss")
     lblTime_1.Caption = lblTime.Caption
     If tmrt >= t_txtInt Then 'Событие Timer произошло
             'при интервале, заданном длительностью
      f = 0
      cmdStart.Enabled = True
      cmdCheck.Enabled = True
      cmdStop.Enabled = False
      tmrSec.Interval = 0
      RaiseEvent Timer
     End If
    End If
   Else
    lblTime.Caption = Format(tmr, "hh:nn:ss")
    lblTime_1.Caption = lblTime.Caption
    If tmr >= t_txtInt Then 'Событие Timer произошло
              'при интервале, заданном границей
     cmdStart.Enabled = True
     cmdCheck.Enabled = True
     cmdStop.Enabled = False
     RaiseEvent Timer
    End If
   End If
  Else
   If f = 1 Then 'Когда приостанавливается интервальный секундомер
    tmr0 = tmr - tmrt  'кнопкой "Стоп", системные часы продолжают
   End If                 'идти, и вслед за ними должна смещаться
                            'начальная точка отсчета времени
   If optType(1).Value = True Then
    lblTime.Caption = Format(tmr, "hh:nn:ss")
    lblTime_1.Caption = lblTime.Caption
   End If
  End If
  If optType(0).Enabled = False And optType(1).Enabled _
                                        = False Then
   lblTime.Caption = Format(tmr, "hh:nn:ss")
   lblTime_1.Caption = lblTime.Caption
  End If
End Sub

Option Explicit
Dim i As Integer, j As Integer
Dim a(1, 99) As Integer 'В этом массиве хранятся 2 "карты":
'простановки крестиков и ноликов; по этим картам проверяется
'условие победы тех или других
DefInt d-z  'Целый тип назначается всем переменным модуля,
               'начинающимся с букв из заданного диапазона
Private Sub chkTime_Click()
 Static c As Integer
 If c Mod 2 = 0 Then
  chkTime.Value = 1
 Else
  chkTime.Value = 0
 End If
 c = c + 1
End Sub
Private Sub clcSec_Timer(Index As Integer)
 If chkTime.Value = 0 Then
  If Index = 0 Then
   lblTablo.Caption = "Победа 'Ноликов'!"
  Else
   lblTablo.Caption = "Победа'Крестиков'!"
  End If
  Call cmdFin_Click
 End If
End Sub
Private Sub cmdField_Click(Index As Integer)
 i = i + 1
 j = i Mod 2
 If cmdStart.Enabled = False And cmdFin.Enabled = True Then
  If cmdField(Index).Caption = "" Then
   cmdField(Index).Caption = Mid("OX", j + 1, 1) 'Изображением
   'нуля служит (для красоты) буква О
   If Proverka(Index, j, a()) = 1 Then
    Exit Sub
   End If
   clcSec(1 - j).Stopp
   clcSec(j).Start
   If j = 0 Then
    lblTablo.Caption = "Ход 'Крестиков'"
   Else
    lblTablo.Caption = "Ход 'Ноликов'"
   End If
  End If
 End If
End Sub

Private Sub cmdField_GotFocus(Index As Integer)
 If cmdSet(0).Enabled = True Then
  cmdSet(0).SetFocus
 End If
End Sub

Private Sub cmdFin_Click()
 Dim x, y As Integer
 clcSec(j).Stopp
 clcSec(1 - j).Stopp
 cmdStart.Enabled = True
 cmdFin.Enabled = False
 For x = 0 To 1
  For y = 0 To 99
   a(x, y) = 0
  Next
 Next
End Sub

Private Sub cmdSet_Click(Index As Integer)
 lblTablo.Caption = ""
 clcSec(Index).Check
 clcSec(Index).Visible = True
 txtSet(Index).Visible = True
 cmdSet(Index).Enabled = False
 If cmdSet(0).Enabled = False And cmdSet(1).Enabled = False Then
  cmdStart.Enabled = True
 End If
End Sub

Private Sub cmdStart_Click()
 Dim x, y
  If (txtSet(0).Text = "00:00:00" Or txtSet(1).Text = "00:00:00") _
           And chkTime.Value = 0 Then
   Exit Sub
  End If
  i = 0
  clcSec(j).Check
  clcSec(1 - j).Check
  clcSec(j).Check
  clcSec(1 - j).Check
  clcSec(j).Visible = True
  clcSec(1 - j).Visible = True
  cmdSet(j).Enabled = False
  cmdSet(1 - j).Enabled = False
  For x = 0 To 99
   cmdField(x).Caption = ""
  Next
  For x = 0 To 1
   For y = 0 To 99
    a(x, y) = 0
   Next
  Next
  clcSec(0).Start
  cmdStart.Enabled = False
  cmdFin.Enabled = True
  lblTablo.Caption = "Ход 'Крестиков'"
End Sub

Private Sub Form_Load()
 lblTablo.Caption = "Добро пожаловать!"
End Sub
Private Sub txtSet_Change(Index As Integer)
 clcSec(Index).Interval = txtSet(Index).Text
End Sub

Private Function Proverka(ind As Integer, ind0 As Integer, _
                           a() As Integer) As Integer
 Dim x, y, z, zz, u, d, dx, mx, ind1, k, s
 'Здесь реализована проверка чьей-либо победы,
 'но понять КАК это сделано труднее, чем написать эту
 'функцию самому
 a(ind0, ind) = 1 'Отображается очередной знак на карте
 For z = 0 To 1 'Сначала проверяем горизонтали и вертикали
  For x = 0 To 9
   s = 0
   k = 0
   For y = 0 To 9
    If z = 0 Then
     ind1 = x + 10 * y
    Else
     ind1 = y + 10 * x
    End If
    s = s + a(ind0, ind1)
    k = k + 1
    If s = k Then
     If s = 5 Then
      If ind0 = 0 Then
       lblTablo.Caption = "Победа 'Ноликов'!"
      Else
       lblTablo.Caption = "Победа'Крестиков'!"
      End If
      Call cmdFin_Click
      Proverka = 1
      Exit Function
     End If
    Else
     s = 0
     k = 0
    End If
   Next
  Next
 Next
 For u = 0 To 1 'Потом проверяем диагонали
  For z = 0 To 5
   If u = 0 Then
    d = 55 - 11 * z
    zz = z + 4
   Else
    d = 45 - 9 * z
    zz = 5 - z
   End If
   If d = 0 Then
    mx = 0
   Else
    mx = 1
   End If
   For x = 0 To mx
   dx = d * x
    s = 0
    k = 0
    For y = 0 To z + 4
     If u = 0 Then
      ind1 = zz + 9 * y + dx
     Else
      ind1 = zz + 11 * y + dx
     End If
     s = s + a(ind0, ind1)
     k = k + 1
     If s = k Then
      If s = 5 Then
       If ind0 = 0 Then
        lblTablo.Caption = "Победа 'Ноликов'!"
       Else
        lblTablo.Caption = "Победа'Крестиков'!"
       End If
       Call cmdFin_Click
       Proverka = 1
       Exit Function
      End If
     Else
      s = 0
      k = 0
     End If
    Next
   Next
  Next
 Next
 Proverka = 0
End Function

Option Explicit
Dim i As Integer
Private Sub cmdStart_Click()
 On Error Resume Next 'При установке связи часты внепрограммные сбои
 If i Mod 2 = 0 Then
  cmdStart.Caption = "CTOП"
  cmdStart.Enabled = False
  brwWB.Navigate "http://www.mkids.ru/"
 Else
  cmdStart.Caption = "Вход в детскую сеть"
  cmdStart.Enabled = True
  brwWB.Stop
 End If
 i = i + 1
End Sub

Private Sub cmdBF_Click(Index As Integer)
 If Index = 0 Then
  brwWB.GoBack
 Else
  brwWB.GoForward
 End If
End Sub

Private Sub brwWB_CommandStateChange(ByVal Command As Long,   _
                                                         ByVal Enable As Boolean)
 Select Case Command
  Case CSC_NAVIGATEBACK     'Внутренняя константа WebBrowser
   cmdBF(0).Enabled = Enable
  Case CSC_NAVIGATEFORWARD 'Внутренняя константа WebBrowser
   cmdBF(1).Enabled = Enable
 End Select
End Sub

Private Sub brwWB_DownloadBegin()
 cmdStart.Enabled = True
End Sub

Private Sub brwWB_DownloadComplete()
 cmdStart.Enabled = False
 lblURL.Caption = brwWB.LocationName
End Sub

Private Sub Form_Resize()
 If Me.WindowState <> vbMinimized Then
  brwWB.Height = ScaleHeight - 2 * lblURL.Height - lblURL.Top
  brwWB.Width = ScaleWidth - 1.5 * cmdStart.Width - lblURL.Left
  lblURL.Width = brwWB.Width
  cmdStart.Left = lblURL.Left + lblURL.Width + 0.25 * cmdStart.Width
  cmdBF(0).Left = cmdStart.Left
  cmdBF(1).Left = cmdStart.Left
 End If
End Sub

Option Explicit
Dim strURL(50) As String
Private Sub cboOthers_Click()
 On Error GoTo Er 'Если возникнет ошибка в процессе соединения, то
                     'то процедура заканчивает работу без последствий
  UserDocument.Hyperlink.NavigateTostrURL(cboOthers.ItemData(cboOthers.ListIndex))
 On Error GoTo 0 'Отключаем описанную обработку ошибки
Er:
End Sub

Private Sub UserDocument_Initialize()
 strURL(0) = "http://www.uic.nnov.ru/~edu/school_13.htm"
 strURL(1) = "http://www.cacedu.unibel.by/partner/sch54"
 strURL(2) = "http://into.nit.spb.su/eng/school/sc56/main.htm"
 strURL(3) = "http://www.pmg17vstu.vinnica.ua"
 'strURL(3) = "http://127.0.0.1/Game.htm" 'Используем для отладки
End Sub

Dim strFamily As String, mintLength As Integer
'Объявлены переменные строкового и целого типов

#17:04:23# 'Время суток
#January 27, 1993# ' Дата
#11/30/1998#
#3-6-93 13:20#
#March 27, 1993 1:20am#
#Apr-2-93#
#4 April 1993#

Dim Arr(20) As String 'Массив размером в 21 строковую величину
Dim Koef(3 To 43) As Double 'Массив в 41 величину типа Double
Dim Point() As Long 'Динамический массив длинных целых
Dim Obj(20) As String, Obj1(20) As String 'Два массива типа String
Dim Obj(20), Obj1(20) As String 'Первый массив типа Variant (по 
                                'умолчанию), второй - String
 

Dim Tab(20, 30) As Integer 'Массив размером в 21*31 целую величину
Dim K_01(14, ­-3 To 43, 2) As Byte 'Массив размером в 15*47*3 байт

Dim var As Variant, arrDate(1000) As Date
var=arrDate()

Dim arrWeek, newDay
arrWeek = Array("Пн", "Вт", "Ср", "Чт", "Пт", "Сб", "Вс")
newDay = arrWeek(2) 'присвоение значения "Ср" переменной newDay	

Dim Y As String
Y = "7"
Print "6" + Y, "6" & Y 'Будет напечатано: 67    67
Print 6 + Y, 6 & Y     'Будет напечатано: 13    67

Dim MyTime As Date, MyDate As Date, MyStr As String
MyTime = #5:04:23 PM# 'Краткий формат даты
MyDate = #1/27/98# 'Краткий формат времени
MyStr = Format(MyTime, "h:m:s") 'Возвращает "17:4:23"
MyStr = Format(MyTime, "hh:mm:ss AMPM") 'Возвращает "05:04:23"
MyStr = Format(MyDate, "dddd, mmmm d yyyy") ' Возвращает 
                                                      '"Среда, Январь 27 1993"
'Если формат не указан, возвращается строка
MyStr = Format(23) 'Возвращает "23"

'Специальные форматы
MyStr = Format(5459.4, "##,##0.00") 'Возвращает "5 459.40"
MyStr = Format(334.9, "###0.00") 'Возвращает"334.90"
MyStr = Format(5, "0.00%") 'Возвращает "500.00%"
MyStr = Format("ПРИВЕТ", "<") 'Возвращает "привет"
MyStr = Format("Вот он какой", ">") 'Возвращает "ВОТ ОН КАКОЙ"

"BAU123khg" Like "B?[N-TV-X]*" 'Вырабатывается значение False.

Const MyNumber = 1001
Public Const MyString = "Вторая школа"
Private Const MyInt As Integer = 5
Const MyStr = "1001 ночь", MySalary As Double = 1E-50

DefInt A-Z
Dim MyVar As Double

Dim AnotherVar, Choice As Boolean, BirthDate As Date
Dim MyMatrix(1 To 5, 4 To 9, 3 To 5) As Double
Dim MyArray() 'Динамический массив типа Variant